Как узнать загрузку процессора?

[makavka]

Доброго времени суток!

Подскажите пожалуйста, как определить уровень загрузки процессора в текущий момент времени под управлением WinXP и Ubuntu 9.04?

Спасибо!

[carrots]

В Linux это очень просто, через tprocess вызываем базовую команду линуха "top" и берем все что нужно.
С Windows наверное будет на много сложнее...

Добавлено спустя 8 минут 51 секунду:
Здесь есть пример на дельфи, как это сделать под винду, фрипаскаль должен потянуть...(сам не пробовал...)
http://www.aldyn.ru/products/cpu_usage/index.html

[makavka]

carrots спасибо за ссылку!

Проблема определения загрузки процессора в WinXp - решена. Пришлось немного изменить пример для делфи, а то фрипаскаль ругался.
Кому интересно -

uCpuUsage.zip

Чтоб заработало необходимо в параметрах компилятора указать -Sd. Вероятно необходимо быть осторожным с -Sd. Вот, что сказано в Free Pascal Users' manual:
-Sd Tells the compiler to be Delphi compatible. This is more strict than the -S2 option, since some fpc extensions are switched off.

В Linux это очень просто, через tprocess

Не могли бы вы рассказать подробнее как это сделать?

[Mr.Smart]

makavka
Поищите по форуму TProcess. Буквально недавно данный вопрос поднимался.

[Attid]

вместо

-Sd

можно вначале юнита написать {$MODE DELPHI} , это если например тебе надо использовать совместимость не во всех юнитах.

Добавлено спустя 1 минуту 8 секунд:
кстати ругалось скорее всего на руботу с указателями, если её передалать то будет и без режима дельфи собираться.

[carrots]

Вот набросал в Лазаре пример.
Уровень нагрузки процессора пишется в переменную FCPUUsage
Дополнительно в лейбы пишу подробную информацию о процессоре, оперативке и свапе.

Код: Выделить всё

unit Unit1;

{$mode objfpc}{$H+}

interface

uses
  Classes, SysUtils, FileUtil, LResources, Forms, Controls, Graphics, Dialogs,
  StdCtrls, ExtCtrls, process;

type

  { TForm1 }

  TForm1 = class(TForm)
    LabelCPU: TLabel;
    LabelCPUUsage: TLabel;
    LabelMEM: TLabel;
    LabelSWAP: TLabel;
    Timer1: TTimer;
    procedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
    procedure Timer1Timer(Sender: TObject);
  private
    { private declarations }
  public
    FTop: tprocess;
    FCPUUsage: single;
    FProcessOut: TStringList;
    { public declarations }
  end;

var
  Form1: TForm1;

implementation

{ TForm1 }

procedure TForm1.FormCreate(Sender: TObject);
begin
  FProcessOut := TStringList.Create;
  FTop := TProcess.Create(Self);
  FTop.CommandLine := 'top -bcisSH';
  FTop.Options := FTop.Options + [poUsePipes, poStderrToOutPut, poDefaultErrorMode];
  FTop.Execute;
end;

procedure TForm1.FormDestroy(Sender: TObject);
begin
  FProcessOut.Free;
end;

procedure TForm1.Timer1Timer(Sender: TObject);
var
  i, i2: integer;
  s: String;
begin
  FProcessOut.AddStrings(FTop.Environment);
  if FTop.Output.NumBytesAvailable > 0 then
  begin
    FProcessOut.LoadFromStream(FTop.Output);
    for i := 0 to FProcessOut.Count-1 do
    begin
      if AnsiPos('Cpu(s):',FProcessOut.Strings[i]) > 0 then
      begin
        LabelCPU.Caption := FProcessOut.Strings[i];
        s := '';
        for i2:= 8 to 12 do
          s := s+ FProcessOut.Strings[i][i2];
        FCPUUsage := StrToFloat(StringReplace(s,' ','',[rfReplaceAll]));
        LabelCPUUsage.Caption:='CPU Usage: '+FloatToStr(FCPUUsage)+'%';
      end;
      if AnsiPos('Mem:',FProcessOut.Strings[i]) > 0 then LabelMEM.Caption := FProcessOut.Strings[i];
      if AnsiPos('Swap:',FProcessOut.Strings[i]) > 0 then LabelSWAP.Caption := FProcessOut.Strings[i];

    end;
  end;
end;

initialization
  {$I unit1.lrs}

end.   

[makavka]

Большое спасибо всем за ответы!!!
Все работает.

carrots спасибо за образец кода!

Поищите по форуму TProcess.

спасибо, поищу

кстати ругалось скорее всего на работу с указателями

ругалось именно на работу с указателями