Уничтожение контрола самим собой

[qivi]

Проект создан как "Приложение", на форме несколько невизуальных компонентов, всё остальное создаётся и уничтожается в рунтайме. Некоторая кнопка уничтожает на форме ряд контролов включая саму себя, уничтожает следующим образом: freeandnil(B1);. При нажатии на эту кнопку программа вылетает (в линуксе после нескольких нажатий в виндовсе после первого). В консоле операционной системы пишет:

WARNING: TLCLComponent.Destroy with LCLRefCount>0. Hint: Maybe the component is processing an event?

гугл транслит:

ВНИМАНИЕ: TLCLComponent.Destroy с LCLRefCount> 0. Подсказка: Может быть, компонент обрабатывает событие?

На попытку B1.LCLRefCount:=0; - выдаёт ошибку.

Как сделать так что б она уничтожала себя и приложение не падало?

[dunin]

...кнопка уничтожает на форме ряд контролов включая саму себя, уничтожает следующим образом: freeandnil(B1);
...

Полный код процедуры в студию плз.

Добавлено спустя 26 секунд:
Всем привет, кстати. давненько тут не был.

[VirtUX]

я делел так:

Код: Выделить всё

unit Unit1;

{$mode objfpc}{$H+}

interface

uses
  Classes, SysUtils, FileUtil, Forms, Controls, Graphics, Dialogs, StdCtrls;

type

  { TForm1 }

  TForm1 = class(TForm)
    procedure FormClick(Sender: TObject);
  private
    { private declarations }
    procedure OnClickB(sender: TObject);
  public
    { public declarations }
  end;

  { TBut }

  TBut = object
  private
    b: TButton;
  public
    procedure Create;
    procedure Destroy;
  end;

var
  Form1: TForm1;
  But: TBut;

implementation

{$R *.lfm}

{ TForm1 }

procedure TForm1.FormClick(Sender: TObject);
begin
  But.Create;
end;

procedure TForm1.OnClickB(sender: TObject);
begin
  But.Destroy;
end;

{ TBut }

procedure TBut.Create;
begin
  b := TButton.Create(Form1);
  b.Parent := Form1;
  //Прочие параметры
  b.OnClick:= @Form1.OnClickB;
end;

procedure TBut.Destroy;
begin
  FreeAndNil(b);
end;

end.


Можно кликать сколько душа пожелает и по форме, и по кнопке

[Odyssey]

Ещё, как вариант, можно вызывать уничтожение через асинхронный вызов (QueueAsyncCall):

Код: Выделить всё

procedure TForm1.DestroyButtons(Data: PtrInt);
begin
   // уничтожаем
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
  Application.QueueAsyncCall(@DestroyButtons, 0);
end;

В этом случае само уничтожение будет происходить уже после того, как отработает обработчик события кнопки.

[qivi]

Odyssey, спасибо то что доктор прописал!

[Timid]

Объект не может уничтожить себя через Free() внутри своего метода - это явное нарушение принципов целостности данных (в том числе ссылочных, которыми по сути являются ссылки на точки входа в функции-обработчики). Как минимум Sender станет равен nil.

Как вариант, Вы можете создать дополнительное событие, не имеющее параметров (Т.е. не имеющее параметра Sender:TObject) и подписать на него один из методов формы. В нем уже и уничтожить объект.

[zub]

>>Объект не может уничтожить себя через Free() внутри своего метода - это явное нарушение принципов целостности данных
Почему? если гарантировано не будет попытки доступа к данным, то почему нет? Сам Free() вобщемто метод и получается уничтожение объекта внутри соего метода))

>>Как минимум Sender станет равен nil
в смысле sender для формы и self для кнопки? он не становится, а ссылается на данные которых уже небудет. Но это не беда, главное гарантировать чтобы по этой ссылке небыло попытки доступа к данным, в onClick кнопки это не гарантируется((

[Timid]

Ну да.
onClick как и любой другой обработчик вызывается ведь из какого-нибудь метода. Например, DoClick. В котором кнопка может быть перерисована, к примеру. Но она ведь уже nil !!!
Не будешь же писать каждый раз проверку на nil для себя после вызова каждого обработчика

[Odyssey]

Но она ведь уже nil !!!
Не будешь же писать каждый раз проверку на nil для себя после вызова каждого обработчика

Проверка на nil тут не поможет. zub прав, Self после уничтожения кнопки не станет равен nil, просто будет указывать на левую память. Определить это в месте вызова нельзя, остаётся только получать runtime error.

[VirtUX]

Не понимаю чем вам не нравится мой пример? Из стека в куче формируем новые объекты; из того же стека разрушаем динамики. Никаких ошибок и рядом не ляжет.